home *** CD-ROM | disk | FTP | other *** search
/ Megahits 3 / Megahits 3 (1994)(GTI - Rhein-Main-Soft)(DE)[!].iso / module / utilities / trackers / protracker / pt-ciaplay.s < prev    next >
Text File  |  1994-10-14  |  25KB  |  1,304 lines
  1. ;**************************************************
  2. ;*    ----- Protracker V2.3A Playroutine -----    *
  3. ;**************************************************
  4.  
  5. DMAWait = 300 ; Set this as low as possible without losing low notes.
  6.  
  7. ; CIA Version 1:
  8. ; Call SetCIAInt to install the interrupt server. Then call mt_init
  9. ; to initialize the song. Playback starts when the mt_enable flag
  10. ; is set to a nonzero value. To end the song and turn off all voices,
  11. ; call mt_end. At last, call ResetCIAInt to remove the interrupt.
  12.  
  13. ; This playroutine is not very fast, optimized or well commented,
  14. ; but all the new commands in PT2.3 should work.
  15. ; If it's not good enough, you'll have to change it yourself.
  16. ; We'll try to write a faster routine soon...
  17.  
  18. ; Changes from V1.0C playroutine:
  19. ; - Vibrato depth changed to be compatible with Noisetracker 2.0.
  20. ;   You'll have to double all vib. depths on old PT modules.
  21. ; - Funk Repeat changed to Invert Loop.
  22. ; - Period set back earlier when stopping an effect.
  23.  
  24. ; You can use this routine to play a module. Just remove the semicolons.
  25. ; Exit by pressing both mousebuttons.
  26. ;
  27. ;main    BSR.S    SetCIAInt
  28. ;    BSR    mt_init
  29. ;    ST    mt_Enable
  30. ;    MOVE.L    4.W,A6
  31. ;    LEA    DOSname(PC),A1
  32. ;    MOVEQ    #0,D0
  33. ;    JSR    LVOOpenLibrary(A6)
  34. ;    TST.L    D0
  35. ;    BEQ.S    theend
  36. ;    MOVE.L    D0,A6
  37. ;wloop    MOVEQ    #10,D1
  38. ;    JSR    LVODelay(A6)
  39. ;    BTST    #6,$BFE001
  40. ;    BNE.S    wloop
  41. ;    BTST    #2,$DFF016
  42. ;    BNE.S    wloop
  43. ;    MOVE.L    A6,A1
  44. ;    MOVE.L    4.W,A6
  45. ;    JSR    LVOCloseLibrary(A6)
  46. ;theend    BSR    mt_end
  47. ;    BSR    ResetCIAInt
  48. ;    RTS
  49. ;
  50. ;DOSname    dc.b "dos.library",0
  51.  
  52. ;---- CIA Interrupt ----
  53.  
  54. AddICRVector    =   -6
  55. RemICRVector    =  -12
  56. LVOOpenResource    = -498
  57. LVOOpenLibrary     = -552
  58. LVOCloseLibrary    = -414
  59. LVODelay    = -198
  60.  
  61. ciatalo = $400
  62. ciatahi = $500
  63. ciatblo = $600
  64. ciatbhi = $700
  65. ciacra  = $E00
  66. ciacrb  = $F00
  67.  
  68. SetCIAInt
  69.     MOVEQ    #2,D6
  70.     LEA    $BFD000,A5
  71.     MOVE.B    #'b',CIAAname+3
  72. SetCIALoop
  73.     MOVEQ    #0,D0
  74.     LEA    CIAAname(PC),A1
  75.     MOVE.L    4.W,A6
  76.     JSR    LVOOpenResource(A6)
  77.     MOVE.L    D0,CIAAbase
  78.     BEQ    mt_Return
  79.  
  80.     LEA    GfxName(PC),A1
  81.     MOVEQ    #0,D0
  82.     JSR    LVOOpenLibrary(A6)
  83.     TST.L    D0
  84.     BEQ    ResetCIAInt
  85.     MOVE.L    D0,A1
  86.     MOVE.W    206(A1),D0    ; DisplayFlags
  87.     BTST    #2,D0        ; PAL?
  88.     BEQ.S    WasNTSC
  89.     MOVE.L    #1773447,D7 ; PAL
  90.     BRA.S    sciask
  91. WasNTSC    MOVE.L    #1789773,D7 ; NTSC
  92. sciask    MOVE.L    D7,TimerValue
  93.     DIVU    #125,D7 ; Default to normal 50 Hz timer
  94.     JSR    CloseLibrary(A6)
  95.  
  96.     MOVE.L    CIAAbase(PC),A6
  97.     CMP.W    #2,D6
  98.     BEQ.S    TryTimerA
  99. TryTimerB
  100.     LEA    MusicIntServer(PC),A1
  101.     MOVEQ    #1,D0    ; Bit 1: Timer B
  102.     JSR    AddICRVector(A6)
  103.     MOVE.L    #1,TimerFlag
  104.     TST.L    D0
  105.     BNE.S    CIAError
  106.     MOVE.L    A5,CIAAaddr
  107.     MOVE.B    D7,ciatblo(A5)
  108.     LSR.W    #8,D7
  109.     MOVE.B    D7,ciatbhi(A5)
  110.     BSET    #0,ciacrb(A5)
  111.     RTS
  112.  
  113. TryTimerA
  114.     LEA    MusicIntServer(PC),A1
  115.     MOVEQ    #0,D0    ; Bit 0: Timer A
  116.     JSR    AddICRVector(A6)
  117.     CLR.L    TimerFlag
  118.     TST.L    D0
  119.     BNE.S    CIAError
  120.     MOVE.L    A5,CIAAaddr
  121.     MOVE.B    D7,ciatalo(A5)
  122.     LSR.W    #8,D7
  123.     MOVE.B    D7,ciatahi(A5)
  124.     BSET    #0,ciacra(A5)
  125.     RTS
  126.  
  127. CIAError
  128.     MOVE.B    #'a',CIAAname+3
  129.     LEA    $BFE001,A5
  130.     SUBQ.W    #1,D6
  131.     BNE    SetCIALoop
  132.     CLR.L    CIAAbase
  133.     RTS
  134.  
  135. ResetCIAInt
  136.     MOVE.L    CIAAbase(PC),D0
  137.     BEQ    mt_Return
  138.     CLR.L    CIAAbase
  139.     MOVE.L    D0,A6
  140.     MOVE.L    CIAAaddr(PC),A5
  141.     TST.L    TimerFlag
  142.     BEQ.S    ResTimerA
  143.  
  144.     BCLR    #0,ciacrb(A5)
  145.     MOVEQ    #1,D0
  146.     BRA.S    RemInt
  147.  
  148. ResTimerA
  149.     BCLR    #0,ciacra(A5)
  150.     MOVEQ    #0,D0
  151. RemInt    LEA    MusicIntServer(PC),A1
  152.     MOVEQ    #0,d0
  153.     JSR    RemICRVector(A6)
  154.     RTS
  155.  
  156. ;---- Tempo ----
  157.  
  158. SetTempo
  159.     MOVE.L    CIAAbase(PC),D2
  160.     BEQ    mt_Return
  161.     CMP.W    #32,D0
  162.     BHS.S    setemsk
  163.     MOVEQ    #32,D0
  164. setemsk    MOVE.W    D0,RealTempo
  165.     MOVE.L    TimerValue(PC),D2
  166.     DIVU    D0,D2
  167.     MOVE.L    CIAAaddr(PC),A4
  168.     MOVE.L    TimerFlag(PC),D0
  169.     BEQ.S    SetTemA
  170.     MOVE.B    D2,ciatblo(A4)
  171.     LSR.W    #8,D2
  172.     MOVE.B    D2,ciatbhi(A4)
  173.     RTS
  174.  
  175. SetTemA    MOVE.B    D2,ciatalo(A4)
  176.     LSR.W    #8,D2
  177.     MOVE.B    D2,ciatahi(A4)
  178.     RTS
  179.  
  180. RealTempo    dc.w 125
  181. CIAAaddr    dc.l 0
  182. CIAAname    dc.b "ciaa.resource",0
  183. CIAAbase    dc.l 0
  184. TimerFlag    dc.l 0
  185. TimerValue    dc.l 0
  186. GfxName        dc.b "graphics.library",0,0
  187.  
  188. MusicIntServer
  189.     dc.l 0,0
  190.     dc.b 2,5 ; type, priority
  191.     dc.l musintname
  192.     dc.l 0,mt_music
  193.  
  194. musintname    dc.b "Protracker MusicInt",0
  195.  
  196. ;---- Playroutine ----
  197.  
  198. n_note        EQU    0  ; W
  199. n_cmd        EQU    2  ; W
  200. n_cmdlo        EQU    3  ; B
  201. n_start        EQU    4  ; L
  202. n_length    EQU    8  ; W
  203. n_loopstart    EQU    10 ; L
  204. n_replen    EQU    14 ; W
  205. n_period    EQU    16 ; W
  206. n_finetune    EQU    18 ; B
  207. n_volume    EQU    19 ; B
  208. n_dmabit    EQU    20 ; W
  209. n_toneportdirec    EQU    22 ; B
  210. n_toneportspeed    EQU    23 ; B
  211. n_wantedperiod    EQU    24 ; W
  212. n_vibratocmd    EQU    26 ; B
  213. n_vibratopos    EQU    27 ; B
  214. n_tremolocmd    EQU    28 ; B
  215. n_tremolopos    EQU    29 ; B
  216. n_wavecontrol    EQU    30 ; B
  217. n_glissfunk    EQU    31 ; B
  218. n_sampleoffset    EQU    32 ; B
  219. n_pattpos    EQU    33 ; B
  220. n_loopcount    EQU    34 ; B
  221. n_funkoffset    EQU    35 ; B
  222. n_wavestart    EQU    36 ; L
  223. n_reallength    EQU    40 ; W
  224.  
  225. mt_init    LEA    mt_data,A0
  226.     MOVE.L    A0,mt_SongDataPtr
  227.     MOVE.L    A0,A1
  228.     LEA    952(A1),A1
  229.     MOVEQ    #127,D0
  230.     MOVEQ    #0,D1
  231. mtloop    MOVE.L    D1,D2
  232.     SUBQ.W    #1,D0
  233. mtloop2    MOVE.B    (A1)+,D1
  234.     CMP.B    D2,D1
  235.     BGT.S    mtloop
  236.     DBRA    D0,mtloop2
  237.     ADDQ.B    #1,D2
  238.             
  239.     LEA    mt_SampleStarts(PC),A1
  240.     ASL.L    #8,D2
  241.     ASL.L    #2,D2
  242.     ADD.L    #1084,D2
  243.     ADD.L    A0,D2
  244.     MOVE.L    D2,A2
  245.     MOVEQ    #30,D0
  246. mtloop3    CLR.L    (A2)
  247.     MOVE.L    A2,(A1)+
  248.     MOVEQ    #0,D1
  249.     MOVE.W    42(A0),D1
  250.     ASL.L    #1,D1
  251.     ADD.L    D1,A2
  252.     ADD.L    #30,A0
  253.     DBRA    D0,mtloop3
  254.  
  255.     OR.B    #2,$BFE001
  256.     MOVE.B    #6,mt_speed
  257.     CLR.B    mt_counter
  258.     CLR.B    mt_SongPos
  259.     CLR.W    mt_PatternPos
  260. mt_end    SF    mt_Enable
  261.     LEA    $DFF000,A0
  262.     CLR.W    $A8(A0)
  263.     CLR.W    $B8(A0)
  264.     CLR.W    $C8(A0)
  265.     CLR.W    $D8(A0)
  266.     MOVE.W    #$F,$DFF096
  267.     RTS
  268.  
  269. mt_music
  270.     MOVEM.L    D0-D4/A0-A6,-(SP)
  271.     TST.B    mt_Enable
  272.     BEQ    mt_exit
  273.     ADDQ.B    #1,mt_counter
  274.     MOVE.B    mt_counter(PC),D0
  275.     CMP.B    mt_speed(PC),D0
  276.     BLO.S    mt_NoNewNote
  277.     CLR.B    mt_counter
  278.     TST.B    mt_PattDelTime2
  279.     BEQ.S    mt_GetNewNote
  280.     BSR.S    mt_NoNewAllChannels
  281.     BRA    mt_dskip
  282.  
  283. mt_NoNewNote
  284.     BSR.S    mt_NoNewAllChannels
  285.     BRA    mt_NoNewPosYet
  286.  
  287. mt_NoNewAllChannels
  288.     LEA    $DFF0A0,A5
  289.     LEA    mt_chan1temp(PC),A6
  290.     BSR    mt_CheckEfx
  291.     LEA    $DFF0B0,A5
  292.     LEA    mt_chan2temp(PC),A6
  293.     BSR    mt_CheckEfx
  294.     LEA    $DFF0C0,A5
  295.     LEA    mt_chan3temp(PC),A6
  296.     BSR    mt_CheckEfx
  297.     LEA    $DFF0D0,A5
  298.     LEA    mt_chan4temp(PC),A6
  299.     BRA    mt_CheckEfx
  300.  
  301. mt_GetNewNote
  302.     MOVE.L    mt_SongDataPtr(PC),A0
  303.     LEA    12(A0),A3
  304.     LEA    952(A0),A2    ;pattpo
  305.     LEA    1084(A0),A0    ;patterndata
  306.     MOVEQ    #0,D0
  307.     MOVEQ    #0,D1
  308.     MOVE.B    mt_SongPos(PC),D0
  309.     MOVE.B    (A2,D0.W),D1
  310.     ASL.L    #8,D1
  311.     ASL.L    #2,D1
  312.     ADD.W    mt_PatternPos(PC),D1
  313.     CLR.W    mt_DMACONtemp
  314.  
  315.     LEA    $DFF0A0,A5
  316.     LEA    mt_chan1temp(PC),A6
  317.     BSR.S    mt_PlayVoice
  318.     LEA    $DFF0B0,A5
  319.     LEA    mt_chan2temp(PC),A6
  320.     BSR.S    mt_PlayVoice
  321.     LEA    $DFF0C0,A5
  322.     LEA    mt_chan3temp(PC),A6
  323.     BSR.S    mt_PlayVoice
  324.     LEA    $DFF0D0,A5
  325.     LEA    mt_chan4temp(PC),A6
  326.     BSR.S    mt_PlayVoice
  327.     BRA    mt_SetDMA
  328.  
  329. mt_PlayVoice
  330.     TST.L    (A6)
  331.     BNE.S    mt_plvskip
  332.     BSR    mt_PerNop
  333. mt_plvskip
  334.     MOVE.L    (A0,D1.L),(A6)
  335.     ADDQ.L    #4,D1
  336.     MOVEQ    #0,D2
  337.     MOVE.B    n_cmd(A6),D2
  338.     AND.B    #$F0,D2
  339.     LSR.B    #4,D2
  340.     MOVE.B    (A6),D0
  341.     AND.B    #$F0,D0
  342.     OR.B    D0,D2
  343.     TST.B    D2
  344.     BEQ    mt_SetRegs
  345.     MOVEQ    #0,D3
  346.     LEA    mt_SampleStarts(PC),A1
  347.     MOVE    D2,D4
  348.     SUBQ.L    #1,D2
  349.     ASL.L    #2,D2
  350.     MULU    #30,D4
  351.     MOVE.L    (A1,D2.L),n_start(A6)
  352.     MOVE.W    (A3,D4.L),n_length(A6)
  353.     MOVE.W    (A3,D4.L),n_reallength(A6)
  354.     MOVE.B    2(A3,D4.L),n_finetune(A6)
  355.     MOVE.B    3(A3,D4.L),n_volume(A6)
  356.     MOVE.W    4(A3,D4.L),D3 ; Get repeat
  357.     TST.W    D3
  358.     BEQ.S    mt_NoLoop
  359.     MOVE.L    n_start(A6),D2    ; Get start
  360.     ASL.W    #1,D3
  361.     ADD.L    D3,D2        ; Add repeat
  362.     MOVE.L    D2,n_loopstart(A6)
  363.     MOVE.L    D2,n_wavestart(A6)
  364.     MOVE.W    4(A3,D4.L),D0    ; Get repeat
  365.     ADD.W    6(A3,D4.L),D0    ; Add replen
  366.     MOVE.W    D0,n_length(A6)
  367.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  368.     MOVEQ    #0,D0
  369.     MOVE.B    n_volume(A6),D0
  370.     MOVE.W    D0,8(A5)    ; Set volume
  371.     BRA.S    mt_SetRegs
  372.  
  373. mt_NoLoop
  374.     MOVE.L    n_start(A6),D2
  375.     ADD.L    D3,D2
  376.     MOVE.L    D2,n_loopstart(A6)
  377.     MOVE.L    D2,n_wavestart(A6)
  378.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  379.     MOVEQ    #0,D0
  380.     MOVE.B    n_volume(A6),D0
  381.     MOVE.W    D0,8(A5)    ; Set volume
  382. mt_SetRegs
  383.     MOVE.W    (A6),D0
  384.     AND.W    #$0FFF,D0
  385.     BEQ    mt_CheckMoreEfx    ; If no note
  386.     MOVE.W    2(A6),D0
  387.     AND.W    #$0FF0,D0
  388.     CMP.W    #$0E50,D0
  389.     BEQ.S    mt_DoSetFineTune
  390.     MOVE.B    2(A6),D0
  391.     AND.B    #$0F,D0
  392.     CMP.B    #3,D0    ; TonePortamento
  393.     BEQ.S    mt_ChkTonePorta
  394.     CMP.B    #5,D0
  395.     BEQ.S    mt_ChkTonePorta
  396.     CMP.B    #9,D0    ; Sample Offset
  397.     BNE.S    mt_SetPeriod
  398.     BSR    mt_CheckMoreEfx
  399.     BRA.S    mt_SetPeriod
  400.  
  401. mt_DoSetFineTune
  402.     BSR    mt_SetFineTune
  403.     BRA.S    mt_SetPeriod
  404.  
  405. mt_ChkTonePorta
  406.     BSR    mt_SetTonePorta
  407.     BRA    mt_CheckMoreEfx
  408.  
  409. mt_SetPeriod
  410.     MOVEM.L    D0-D1/A0-A1,-(SP)
  411.     MOVE.W    (A6),D1
  412.     AND.W    #$0FFF,D1
  413.     LEA    mt_PeriodTable(PC),A1
  414.     MOVEQ    #0,D0
  415.     MOVEQ    #36,D2
  416. mt_ftuloop
  417.     CMP.W    (A1,D0.W),D1
  418.     BHS.S    mt_ftufound
  419.     ADDQ.L    #2,D0
  420.     DBRA    D2,mt_ftuloop
  421. mt_ftufound
  422.     MOVEQ    #0,D1
  423.     MOVE.B    n_finetune(A6),D1
  424.     MULU    #36*2,D1
  425.     ADD.L    D1,A1
  426.     MOVE.W    (A1,D0.W),n_period(A6)
  427.     MOVEM.L    (SP)+,D0-D1/A0-A1
  428.  
  429.     MOVE.W    2(A6),D0
  430.     AND.W    #$0FF0,D0
  431.     CMP.W    #$0ED0,D0 ; Notedelay
  432.     BEQ    mt_CheckMoreEfx
  433.  
  434.     MOVE.W    n_dmabit(A6),$DFF096
  435.     BTST    #2,n_wavecontrol(A6)
  436.     BNE.S    mt_vibnoc
  437.     CLR.B    n_vibratopos(A6)
  438. mt_vibnoc
  439.     BTST    #6,n_wavecontrol(A6)
  440.     BNE.S    mt_trenoc
  441.     CLR.B    n_tremolopos(A6)
  442. mt_trenoc
  443.     MOVE.L    n_start(A6),(A5)    ; Set start
  444.     MOVE.W    n_length(A6),4(A5)    ; Set length
  445.     MOVE.W    n_period(A6),D0
  446.     MOVE.W    D0,6(A5)        ; Set period
  447.     MOVE.W    n_dmabit(A6),D0
  448.     OR.W    D0,mt_DMACONtemp
  449.     BRA    mt_CheckMoreEfx
  450.  
  451. mt_SetDMA
  452.     MOVE.W    #300,D0
  453. mt_WaitDMA
  454.     DBRA    D0,mt_WaitDMA
  455.     MOVE.W    mt_DMACONtemp(PC),D0
  456.     OR.W    #$8000,D0
  457.     MOVE.W    D0,$DFF096
  458.     MOVE.W    #300,D0
  459. mt_WaitDMA2
  460.     DBRA    D0,mt_WaitDMA2
  461.  
  462.     LEA    $DFF000,A5
  463.     LEA    mt_chan4temp(PC),A6
  464.     MOVE.L    n_loopstart(A6),$D0(A5)
  465.     MOVE.W    n_replen(A6),$D4(A5)
  466.     LEA    mt_chan3temp(PC),A6
  467.     MOVE.L    n_loopstart(A6),$C0(A5)
  468.     MOVE.W    n_replen(A6),$C4(A5)
  469.     LEA    mt_chan2temp(PC),A6
  470.     MOVE.L    n_loopstart(A6),$B0(A5)
  471.     MOVE.W    n_replen(A6),$B4(A5)
  472.     LEA    mt_chan1temp(PC),A6
  473.     MOVE.L    n_loopstart(A6),$A0(A5)
  474.     MOVE.W    n_replen(A6),$A4(A5)
  475.  
  476. mt_dskip
  477.     ADD.W    #16,mt_PatternPos
  478.     MOVE.B    mt_PattDelTime,D0
  479.     BEQ.S    mt_dskc
  480.     MOVE.B    D0,mt_PattDelTime2
  481.     CLR.B    mt_PattDelTime
  482. mt_dskc    TST.B    mt_PattDelTime2
  483.     BEQ.S    mt_dska
  484.     SUBQ.B    #1,mt_PattDelTime2
  485.     BEQ.S    mt_dska
  486.     SUB.W    #16,mt_PatternPos
  487. mt_dska    TST.B    mt_PBreakFlag
  488.     BEQ.S    mt_nnpysk
  489.     SF    mt_PBreakFlag
  490.     MOVEQ    #0,D0
  491.     MOVE.B    mt_PBreakPos(PC),D0
  492.     CLR.B    mt_PBreakPos
  493.     LSL.W    #4,D0
  494.     MOVE.W    D0,mt_PatternPos
  495. mt_nnpysk
  496.     CMP.W    #1024,mt_PatternPos
  497.     BLO.S    mt_NoNewPosYet
  498. mt_NextPosition    
  499.     MOVEQ    #0,D0
  500.     MOVE.B    mt_PBreakPos(PC),D0
  501.     LSL.W    #4,D0
  502.     MOVE.W    D0,mt_PatternPos
  503.     CLR.B    mt_PBreakPos
  504.     CLR.B    mt_PosJumpFlag
  505.     ADDQ.B    #1,mt_SongPos
  506.     AND.B    #$7F,mt_SongPos
  507.     MOVE.B    mt_SongPos(PC),D1
  508.     MOVE.L    mt_SongDataPtr(PC),A0
  509.     CMP.B    950(A0),D1
  510.     BLO.S    mt_NoNewPosYet
  511.     CLR.B    mt_SongPos
  512. mt_NoNewPosYet    
  513.     TST.B    mt_PosJumpFlag
  514.     BNE.S    mt_NextPosition
  515. mt_exit    MOVEM.L    (SP)+,D0-D4/A0-A6
  516.     RTS
  517.  
  518. mt_CheckEfx
  519.     BSR    mt_UpdateFunk
  520.     MOVE.W    n_cmd(A6),D0
  521.     AND.W    #$0FFF,D0
  522.     BEQ.S    mt_PerNop
  523.     MOVE.B    n_cmd(A6),D0
  524.     AND.B    #$0F,D0
  525.     BEQ.S    mt_Arpeggio
  526.     CMP.B    #1,D0
  527.     BEQ    mt_PortaUp
  528.     CMP.B    #2,D0
  529.     BEQ    mt_PortaDown
  530.     CMP.B    #3,D0
  531.     BEQ    mt_TonePortamento
  532.     CMP.B    #4,D0
  533.     BEQ    mt_Vibrato
  534.     CMP.B    #5,D0
  535.     BEQ    mt_TonePlusVolSlide
  536.     CMP.B    #6,D0
  537.     BEQ    mt_VibratoPlusVolSlide
  538.     CMP.B    #$E,D0
  539.     BEQ    mt_E_Commands
  540. SetBack    MOVE.W    n_period(A6),6(A5)
  541.     CMP.B    #7,D0
  542.     BEQ    mt_Tremolo
  543.     CMP.B    #$A,D0
  544.     BEQ    mt_VolumeSlide
  545. mt_Return
  546.     RTS
  547.  
  548. mt_PerNop
  549.     MOVE.W    n_period(A6),6(A5)
  550.     RTS
  551.  
  552. mt_Arpeggio
  553.     MOVEQ    #0,D0
  554.     MOVE.B    mt_counter(PC),D0
  555.     DIVS    #3,D0
  556.     SWAP    D0
  557.     CMP.W    #0,D0
  558.     BEQ.S    mt_Arpeggio2
  559.     CMP.W    #2,D0
  560.     BEQ.S    mt_Arpeggio1
  561.     MOVEQ    #0,D0
  562.     MOVE.B    n_cmdlo(A6),D0
  563.     LSR.B    #4,D0
  564.     BRA.S    mt_Arpeggio3
  565.  
  566. mt_Arpeggio1
  567.     MOVEQ    #0,D0
  568.     MOVE.B    n_cmdlo(A6),D0
  569.     AND.B    #15,D0
  570.     BRA.S    mt_Arpeggio3
  571.  
  572. mt_Arpeggio2
  573.     MOVE.W    n_period(A6),D2
  574.     BRA.S    mt_Arpeggio4
  575.  
  576. mt_Arpeggio3
  577.     ASL.W    #1,D0
  578.     MOVEQ    #0,D1
  579.     MOVE.B    n_finetune(A6),D1
  580.     MULU    #36*2,D1
  581.     LEA    mt_PeriodTable(PC),A0
  582.     ADD.L    D1,A0
  583.     MOVEQ    #0,D1
  584.     MOVE.W    n_period(A6),D1
  585.     MOVEQ    #36,D3
  586. mt_arploop
  587.     MOVE.W    (A0,D0.W),D2
  588.     CMP.W    (A0),D1
  589.     BHS.S    mt_Arpeggio4
  590.     ADDQ.L    #2,A0
  591.     DBRA    D3,mt_arploop
  592.     RTS
  593.  
  594. mt_Arpeggio4
  595.     MOVE.W    D2,6(A5)
  596.     RTS
  597.  
  598. mt_FinePortaUp
  599.     TST.B    mt_counter
  600.     BNE.S    mt_Return
  601.     MOVE.B    #$0F,mt_LowMask
  602. mt_PortaUp
  603.     MOVEQ    #0,D0
  604.     MOVE.B    n_cmdlo(A6),D0
  605.     AND.B    mt_LowMask(PC),D0
  606.     MOVE.B    #$FF,mt_LowMask
  607.     SUB.W    D0,n_period(A6)
  608.     MOVE.W    n_period(A6),D0
  609.     AND.W    #$0FFF,D0
  610.     CMP.W    #113,D0
  611.     BPL.S    mt_PortaUskip
  612.     AND.W    #$F000,n_period(A6)
  613.     OR.W    #113,n_period(A6)
  614. mt_PortaUskip
  615.     MOVE.W    n_period(A6),D0
  616.     AND.W    #$0FFF,D0
  617.     MOVE.W    D0,6(A5)
  618.     RTS    
  619.  
  620. mt_FinePortaDown
  621.     TST.B    mt_counter
  622.     BNE    mt_Return
  623.     MOVE.B    #$0F,mt_LowMask
  624. mt_PortaDown
  625.     CLR.W    D0
  626.     MOVE.B    n_cmdlo(A6),D0
  627.     AND.B    mt_LowMask(PC),D0
  628.     MOVE.B    #$FF,mt_LowMask
  629.     ADD.W    D0,n_period(A6)
  630.     MOVE.W    n_period(A6),D0
  631.     AND.W    #$0FFF,D0
  632.     CMP.W    #856,D0
  633.     BMI.S    mt_PortaDskip
  634.     AND.W    #$F000,n_period(A6)
  635.     OR.W    #856,n_period(A6)
  636. mt_PortaDskip
  637.     MOVE.W    n_period(A6),D0
  638.     AND.W    #$0FFF,D0
  639.     MOVE.W    D0,6(A5)
  640.     RTS
  641.  
  642. mt_SetTonePorta
  643.     MOVE.L    A0,-(SP)
  644.     MOVE.W    (A6),D2
  645.     AND.W    #$0FFF,D2
  646.     MOVEQ    #0,D0
  647.     MOVE.B    n_finetune(A6),D0
  648.     MULU    #36*2,D0 ;37?
  649.     LEA    mt_PeriodTable(PC),A0
  650.     ADD.L    D0,A0
  651.     MOVEQ    #0,D0
  652. mt_StpLoop
  653.     CMP.W    (A0,D0.W),D2
  654.     BHS.S    mt_StpFound
  655.     ADDQ.W    #2,D0
  656.     CMP.W    #36*2,D0 ;37?
  657.     BLO.S    mt_StpLoop
  658.     MOVEQ    #35*2,D0
  659. mt_StpFound
  660.     MOVE.B    n_finetune(A6),D2
  661.     AND.B    #8,D2
  662.     BEQ.S    mt_StpGoss
  663.     TST.W    D0
  664.     BEQ.S    mt_StpGoss
  665.     SUBQ.W    #2,D0
  666. mt_StpGoss
  667.     MOVE.W    (A0,D0.W),D2
  668.     MOVE.L    (SP)+,A0
  669.     MOVE.W    D2,n_wantedperiod(A6)
  670.     MOVE.W    n_period(A6),D0
  671.     CLR.B    n_toneportdirec(A6)
  672.     CMP.W    D0,D2
  673.     BEQ.S    mt_ClearTonePorta
  674.     BGE    mt_Return
  675.     MOVE.B    #1,n_toneportdirec(A6)
  676.     RTS
  677.  
  678. mt_ClearTonePorta
  679.     CLR.W    n_wantedperiod(A6)
  680.     RTS
  681.  
  682. mt_TonePortamento
  683.     MOVE.B    n_cmdlo(A6),D0
  684.     BEQ.S    mt_TonePortNoChange
  685.     MOVE.B    D0,n_toneportspeed(A6)
  686.     CLR.B    n_cmdlo(A6)
  687. mt_TonePortNoChange
  688.     TST.W    n_wantedperiod(A6)
  689.     BEQ    mt_Return
  690.     MOVEQ    #0,D0
  691.     MOVE.B    n_toneportspeed(A6),D0
  692.     TST.B    n_toneportdirec(A6)
  693.     BNE.S    mt_TonePortaUp
  694. mt_TonePortaDown
  695.     ADD.W    D0,n_period(A6)
  696.     MOVE.W    n_wantedperiod(A6),D0
  697.     CMP.W    n_period(A6),D0
  698.     BGT.S    mt_TonePortaSetPer
  699.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  700.     CLR.W    n_wantedperiod(A6)
  701.     BRA.S    mt_TonePortaSetPer
  702.  
  703. mt_TonePortaUp
  704.     SUB.W    D0,n_period(A6)
  705.     MOVE.W    n_wantedperiod(A6),D0
  706.     CMP.W    n_period(A6),D0
  707.     BLT.S    mt_TonePortaSetPer
  708.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  709.     CLR.W    n_wantedperiod(A6)
  710.  
  711. mt_TonePortaSetPer
  712.     MOVE.W    n_period(A6),D2
  713.     MOVE.B    n_glissfunk(A6),D0
  714.     AND.B    #$0F,D0
  715.     BEQ.S    mt_GlissSkip
  716.     MOVEQ    #0,D0
  717.     MOVE.B    n_finetune(A6),D0
  718.     MULU    #36*2,D0
  719.     LEA    mt_PeriodTable(PC),A0
  720.     ADD.L    D0,A0
  721.     MOVEQ    #0,D0
  722. mt_GlissLoop
  723.     CMP.W    (A0,D0.W),D2
  724.     BHS.S    mt_GlissFound
  725.     ADDQ.W    #2,D0
  726.     CMP.W    #36*2,D0
  727.     BLO.S    mt_GlissLoop
  728.     MOVEQ    #35*2,D0
  729. mt_GlissFound
  730.     MOVE.W    (A0,D0.W),D2
  731. mt_GlissSkip
  732.     MOVE.W    D2,6(A5) ; Set period
  733.     RTS
  734.  
  735. mt_Vibrato
  736.     MOVE.B    n_cmdlo(A6),D0
  737.     BEQ.S    mt_Vibrato2
  738.     MOVE.B    n_vibratocmd(A6),D2
  739.     AND.B    #$0F,D0
  740.     BEQ.S    mt_vibskip
  741.     AND.B    #$F0,D2
  742.     OR.B    D0,D2
  743. mt_vibskip
  744.     MOVE.B    n_cmdlo(A6),D0
  745.     AND.B    #$F0,D0
  746.     BEQ.S    mt_vibskip2
  747.     AND.B    #$0F,D2
  748.     OR.B    D0,D2
  749. mt_vibskip2
  750.     MOVE.B    D2,n_vibratocmd(A6)
  751. mt_Vibrato2
  752.     MOVE.B    n_vibratopos(A6),D0
  753.     LEA    mt_VibratoTable(PC),A4
  754.     LSR.W    #2,D0
  755.     AND.W    #$001F,D0
  756.     MOVEQ    #0,D2
  757.     MOVE.B    n_wavecontrol(A6),D2
  758.     AND.B    #$03,D2
  759.     BEQ.S    mt_vib_sine
  760.     LSL.B    #3,D0
  761.     CMP.B    #1,D2
  762.     BEQ.S    mt_vib_rampdown
  763.     MOVE.B    #255,D2
  764.     BRA.S    mt_vib_set
  765. mt_vib_rampdown
  766.     TST.B    n_vibratopos(A6)
  767.     BPL.S    mt_vib_rampdown2
  768.     MOVE.B    #255,D2
  769.     SUB.B    D0,D2
  770.     BRA.S    mt_vib_set
  771. mt_vib_rampdown2
  772.     MOVE.B    D0,D2
  773.     BRA.S    mt_vib_set
  774. mt_vib_sine
  775.     MOVE.B    (A4,D0.W),D2
  776. mt_vib_set
  777.     MOVE.B    n_vibratocmd(A6),D0
  778.     AND.W    #15,D0
  779.     MULU    D0,D2
  780.     LSR.W    #7,D2
  781.     MOVE.W    n_period(A6),D0
  782.     TST.B    n_vibratopos(A6)
  783.     BMI.S    mt_VibratoNeg
  784.     ADD.W    D2,D0
  785.     BRA.S    mt_Vibrato3
  786. mt_VibratoNeg
  787.     SUB.W    D2,D0
  788. mt_Vibrato3
  789.     MOVE.W    D0,6(A5)
  790.     MOVE.B    n_vibratocmd(A6),D0
  791.     LSR.W    #2,D0
  792.     AND.W    #$003C,D0
  793.     ADD.B    D0,n_vibratopos(A6)
  794.     RTS
  795.  
  796. mt_TonePlusVolSlide
  797.     BSR    mt_TonePortNoChange
  798.     BRA    mt_VolumeSlide
  799.  
  800. mt_VibratoPlusVolSlide
  801.     BSR.S    mt_Vibrato2
  802.     BRA    mt_VolumeSlide
  803.  
  804. mt_Tremolo
  805.     MOVE.B    n_cmdlo(A6),D0
  806.     BEQ.S    mt_Tremolo2
  807.     MOVE.B    n_tremolocmd(A6),D2
  808.     AND.B    #$0F,D0
  809.     BEQ.S    mt_treskip
  810.     AND.B    #$F0,D2
  811.     OR.B    D0,D2
  812. mt_treskip
  813.     MOVE.B    n_cmdlo(A6),D0
  814.     AND.B    #$F0,D0
  815.     BEQ.S    mt_treskip2
  816.     AND.B    #$0F,D2
  817.     OR.B    D0,D2
  818. mt_treskip2
  819.     MOVE.B    D2,n_tremolocmd(A6)
  820. mt_Tremolo2
  821.     MOVE.B    n_tremolopos(A6),D0
  822.     LEA    mt_VibratoTable(PC),A4
  823.     LSR.W    #2,D0
  824.     AND.W    #$001F,D0
  825.     MOVEQ    #0,D2
  826.     MOVE.B    n_wavecontrol(A6),D2
  827.     LSR.B    #4,D2
  828.     AND.B    #$03,D2
  829.     BEQ.S    mt_tre_sine
  830.     LSL.B    #3,D0
  831.     CMP.B    #1,D2
  832.     BEQ.S    mt_tre_rampdown
  833.     MOVE.B    #255,D2
  834.     BRA.S    mt_tre_set
  835. mt_tre_rampdown
  836.     TST.B    n_vibratopos(A6)
  837.     BPL.S    mt_tre_rampdown2
  838.     MOVE.B    #255,D2
  839.     SUB.B    D0,D2
  840.     BRA.S    mt_tre_set
  841. mt_tre_rampdown2
  842.     MOVE.B    D0,D2
  843.     BRA.S    mt_tre_set
  844. mt_tre_sine
  845.     MOVE.B    (A4,D0.W),D2
  846. mt_tre_set
  847.     MOVE.B    n_tremolocmd(A6),D0
  848.     AND.W    #15,D0
  849.     MULU    D0,D2
  850.     LSR.W    #6,D2
  851.     MOVEQ    #0,D0
  852.     MOVE.B    n_volume(A6),D0
  853.     TST.B    n_tremolopos(A6)
  854.     BMI.S    mt_TremoloNeg
  855.     ADD.W    D2,D0
  856.     BRA.S    mt_Tremolo3
  857. mt_TremoloNeg
  858.     SUB.W    D2,D0
  859. mt_Tremolo3
  860.     BPL.S    mt_TremoloSkip
  861.     CLR.W    D0
  862. mt_TremoloSkip
  863.     CMP.W    #$40,D0
  864.     BLS.S    mt_TremoloOk
  865.     MOVE.W    #$40,D0
  866. mt_TremoloOk
  867.     MOVE.W    D0,8(A5)
  868.     MOVE.B    n_tremolocmd(A6),D0
  869.     LSR.W    #2,D0
  870.     AND.W    #$003C,D0
  871.     ADD.B    D0,n_tremolopos(A6)
  872.     RTS
  873.  
  874. mt_SampleOffset
  875.     MOVEQ    #0,D0
  876.     MOVE.B    n_cmdlo(A6),D0
  877.     BEQ.S    mt_sononew
  878.     MOVE.B    D0,n_sampleoffset(A6)
  879. mt_sononew
  880.     MOVE.B    n_sampleoffset(A6),D0
  881.     LSL.W    #7,D0
  882.     CMP.W    n_length(A6),D0
  883.     BGE.S    mt_sofskip
  884.     SUB.W    D0,n_length(A6)
  885.     LSL.W    #1,D0
  886.     ADD.L    D0,n_start(A6)
  887.     RTS
  888. mt_sofskip
  889.     MOVE.W    #$0001,n_length(A6)
  890.     RTS
  891.  
  892. mt_VolumeSlide
  893.     MOVEQ    #0,D0
  894.     MOVE.B    n_cmdlo(A6),D0
  895.     LSR.B    #4,D0
  896.     TST.B    D0
  897.     BEQ.S    mt_VolSlideDown
  898. mt_VolSlideUp
  899.     ADD.B    D0,n_volume(A6)
  900.     CMP.B    #$40,n_volume(A6)
  901.     BMI.S    mt_vsuskip
  902.     MOVE.B    #$40,n_volume(A6)
  903. mt_vsuskip
  904.     MOVE.B    n_volume(A6),D0
  905.     MOVE.W    D0,8(A5)
  906.     RTS
  907.  
  908. mt_VolSlideDown
  909.     MOVEQ    #0,D0
  910.     MOVE.B    n_cmdlo(A6),D0
  911.     AND.B    #$0F,D0
  912. mt_VolSlideDown2
  913.     SUB.B    D0,n_volume(A6)
  914.     BPL.S    mt_vsdskip
  915.     CLR.B    n_volume(A6)
  916. mt_vsdskip
  917.     MOVE.B    n_volume(A6),D0
  918.     MOVE.W    D0,8(A5)
  919.     RTS
  920.  
  921. mt_PositionJump
  922.     MOVE.B    n_cmdlo(A6),D0
  923.     SUBQ.B    #1,D0
  924.     MOVE.B    D0,mt_SongPos
  925. mt_pj2    CLR.B    mt_PBreakPos
  926.     ST     mt_PosJumpFlag
  927.     RTS
  928.  
  929. mt_VolumeChange
  930.     MOVEQ    #0,D0
  931.     MOVE.B    n_cmdlo(A6),D0
  932.     CMP.B    #$40,D0
  933.     BLS.S    mt_VolumeOk
  934.     MOVEQ    #$40,D0
  935. mt_VolumeOk
  936.     MOVE.B    D0,n_volume(A6)
  937.     MOVE.W    D0,8(A5)
  938.     RTS
  939.  
  940. mt_PatternBreak
  941.     MOVEQ    #0,D0
  942.     MOVE.B    n_cmdlo(A6),D0
  943.     MOVE.L    D0,D2
  944.     LSR.B    #4,D0
  945.     MULU    #10,D0
  946.     AND.B    #$0F,D2
  947.     ADD.B    D2,D0
  948.     CMP.B    #63,D0
  949.     BHI.S    mt_pj2
  950.     MOVE.B    D0,mt_PBreakPos
  951.     ST    mt_PosJumpFlag
  952.     RTS
  953.  
  954. mt_SetSpeed
  955.     MOVEQ    #0,D0
  956.     MOVE.B    3(A6),D0
  957.     BEQ    mt_end
  958.     CMP.B    #32,D0
  959.     BHS    SetTempo
  960.     CLR.B    mt_counter
  961.     MOVE.B    D0,mt_speed
  962.     RTS
  963.  
  964. mt_CheckMoreEfx
  965.     BSR    mt_UpdateFunk
  966.     MOVE.B    2(A6),D0
  967.     AND.B    #$0F,D0
  968.     CMP.B    #$9,D0
  969.     BEQ    mt_SampleOffset
  970.     CMP.B    #$B,D0
  971.     BEQ    mt_PositionJump
  972.     CMP.B    #$D,D0
  973.     BEQ.S    mt_PatternBreak
  974.     CMP.B    #$E,D0
  975.     BEQ.S    mt_E_Commands
  976.     CMP.B    #$F,D0
  977.     BEQ.S    mt_SetSpeed
  978.     CMP.B    #$C,D0
  979.     BEQ    mt_VolumeChange
  980.     BRA    mt_PerNop
  981.  
  982. mt_E_Commands
  983.     MOVE.B    n_cmdlo(A6),D0
  984.     AND.B    #$F0,D0
  985.     LSR.B    #4,D0
  986.     BEQ.S    mt_FilterOnOff
  987.     CMP.B    #1,D0
  988.     BEQ    mt_FinePortaUp
  989.     CMP.B    #2,D0
  990.     BEQ    mt_FinePortaDown
  991.     CMP.B    #3,D0
  992.     BEQ.S    mt_SetGlissControl
  993.     CMP.B    #4,D0
  994.     BEQ    mt_SetVibratoControl
  995.     CMP.B    #5,D0
  996.     BEQ    mt_SetFineTune
  997.     CMP.B    #6,D0
  998.     BEQ    mt_JumpLoop
  999.     CMP.B    #7,D0
  1000.     BEQ    mt_SetTremoloControl
  1001.     CMP.B    #9,D0
  1002.     BEQ    mt_RetrigNote
  1003.     CMP.B    #$A,D0
  1004.     BEQ    mt_VolumeFineUp
  1005.     CMP.B    #$B,D0
  1006.     BEQ    mt_VolumeFineDown
  1007.     CMP.B    #$C,D0
  1008.     BEQ    mt_NoteCut
  1009.     CMP.B    #$D,D0
  1010.     BEQ    mt_NoteDelay
  1011.     CMP.B    #$E,D0
  1012.     BEQ    mt_PatternDelay
  1013.     CMP.B    #$F,D0
  1014.     BEQ    mt_FunkIt
  1015.     RTS
  1016.  
  1017. mt_FilterOnOff
  1018.     MOVE.B    n_cmdlo(A6),D0
  1019.     AND.B    #1,D0
  1020.     ASL.B    #1,D0
  1021.     AND.B    #$FD,$BFE001
  1022.     OR.B    D0,$BFE001
  1023.     RTS    
  1024.  
  1025. mt_SetGlissControl
  1026.     MOVE.B    n_cmdlo(A6),D0
  1027.     AND.B    #$0F,D0
  1028.     AND.B    #$F0,n_glissfunk(A6)
  1029.     OR.B    D0,n_glissfunk(A6)
  1030.     RTS
  1031.  
  1032. mt_SetVibratoControl
  1033.     MOVE.B    n_cmdlo(A6),D0
  1034.     AND.B    #$0F,D0
  1035.     AND.B    #$F0,n_wavecontrol(A6)
  1036.     OR.B    D0,n_wavecontrol(A6)
  1037.     RTS
  1038.  
  1039. mt_SetFineTune
  1040.     MOVE.B    n_cmdlo(A6),D0
  1041.     AND.B    #$0F,D0
  1042.     MOVE.B    D0,n_finetune(A6)
  1043.     RTS
  1044.  
  1045. mt_JumpLoop
  1046.     TST.B    mt_counter
  1047.     BNE    mt_Return
  1048.     MOVE.B    n_cmdlo(A6),D0
  1049.     AND.B    #$0F,D0
  1050.     BEQ.S    mt_SetLoop
  1051.     TST.B    n_loopcount(A6)
  1052.     BEQ.S    mt_jumpcnt
  1053.     SUBQ.B    #1,n_loopcount(A6)
  1054.     BEQ    mt_Return
  1055. mt_jmploop    MOVE.B    n_pattpos(A6),mt_PBreakPos
  1056.     ST    mt_PBreakFlag
  1057.     RTS
  1058.  
  1059. mt_jumpcnt
  1060.     MOVE.B    D0,n_loopcount(A6)
  1061.     BRA.S    mt_jmploop
  1062.  
  1063. mt_SetLoop
  1064.     MOVE.W    mt_PatternPos(PC),D0
  1065.     LSR.W    #4,D0
  1066.     MOVE.B    D0,n_pattpos(A6)
  1067.     RTS
  1068.  
  1069. mt_SetTremoloControl
  1070.     MOVE.B    n_cmdlo(A6),D0
  1071.     AND.B    #$0F,D0
  1072.     LSL.B    #4,D0
  1073.     AND.B    #$0F,n_wavecontrol(A6)
  1074.     OR.B    D0,n_wavecontrol(A6)
  1075.     RTS
  1076.  
  1077. mt_RetrigNote
  1078.     MOVE.L    D1,-(SP)
  1079.     MOVEQ    #0,D0
  1080.     MOVE.B    n_cmdlo(A6),D0
  1081.     AND.B    #$0F,D0
  1082.     BEQ.S    mt_rtnend
  1083.     MOVEQ    #0,D1
  1084.     MOVE.B    mt_counter(PC),D1
  1085.     BNE.S    mt_rtnskp
  1086.     MOVE.W    (A6),D1
  1087.     AND.W    #$0FFF,D1
  1088.     BNE.S    mt_rtnend
  1089.     MOVEQ    #0,D1
  1090.     MOVE.B    mt_counter(PC),D1
  1091. mt_rtnskp
  1092.     DIVU    D0,D1
  1093.     SWAP    D1
  1094.     TST.W    D1
  1095.     BNE.S    mt_rtnend
  1096. mt_DoRetrig
  1097.     MOVE.W    n_dmabit(A6),$DFF096    ; Channel DMA off
  1098.     MOVE.L    n_start(A6),(A5)    ; Set sampledata pointer
  1099.     MOVE.W    n_length(A6),4(A5)    ; Set length
  1100.     MOVE.W    #300,D0
  1101. mt_rtnloop1
  1102.     DBRA    D0,mt_rtnloop1
  1103.     MOVE.W    n_dmabit(A6),D0
  1104.     BSET    #15,D0
  1105.     MOVE.W    D0,$DFF096
  1106.     MOVE.W    #300,D0
  1107. mt_rtnloop2
  1108.     DBRA    D0,mt_rtnloop2
  1109.     MOVE.L    n_loopstart(A6),(A5)
  1110.     MOVE.L    n_replen(A6),4(A5)
  1111. mt_rtnend
  1112.     MOVE.L    (SP)+,D1
  1113.     RTS
  1114.  
  1115. mt_VolumeFineUp
  1116.     TST.B    mt_counter
  1117.     BNE    mt_Return
  1118.     MOVEQ    #0,D0
  1119.     MOVE.B    n_cmdlo(A6),D0
  1120.     AND.B    #$F,D0
  1121.     BRA    mt_VolSlideUp
  1122.  
  1123. mt_VolumeFineDown
  1124.     TST.B    mt_counter
  1125.     BNE    mt_Return
  1126.     MOVEQ    #0,D0
  1127.     MOVE.B    n_cmdlo(A6),D0
  1128.     AND.B    #$0F,D0
  1129.     BRA    mt_VolSlideDown2
  1130.  
  1131. mt_NoteCut
  1132.     MOVEQ    #0,D0
  1133.     MOVE.B    n_cmdlo(A6),D0
  1134.     AND.B    #$0F,D0
  1135.     CMP.B    mt_counter(PC),D0
  1136.     BNE    mt_Return
  1137.     CLR.B    n_volume(A6)
  1138.     MOVE.W    #0,8(A5)
  1139.     RTS
  1140.  
  1141. mt_NoteDelay
  1142.     MOVEQ    #0,D0
  1143.     MOVE.B    n_cmdlo(A6),D0
  1144.     AND.B    #$0F,D0
  1145.     CMP.B    mt_Counter,D0
  1146.     BNE    mt_Return
  1147.     MOVE.W    (A6),D0
  1148.     BEQ    mt_Return
  1149.     MOVE.L    D1,-(SP)
  1150.     BRA    mt_DoRetrig
  1151.  
  1152. mt_PatternDelay
  1153.     TST.B    mt_counter
  1154.     BNE    mt_Return
  1155.     MOVEQ    #0,D0
  1156.     MOVE.B    n_cmdlo(A6),D0
  1157.     AND.B    #$0F,D0
  1158.     TST.B    mt_PattDelTime2
  1159.     BNE    mt_Return
  1160.     ADDQ.B    #1,D0
  1161.     MOVE.B    D0,mt_PattDelTime
  1162.     RTS
  1163.  
  1164. mt_FunkIt
  1165.     TST.B    mt_counter
  1166.     BNE    mt_Return
  1167.     MOVE.B    n_cmdlo(A6),D0
  1168.     AND.B    #$0F,D0
  1169.     LSL.B    #4,D0
  1170.     AND.B    #$0F,n_glissfunk(A6)
  1171.     OR.B    D0,n_glissfunk(A6)
  1172.     TST.B    D0
  1173.     BEQ    mt_Return
  1174. mt_UpdateFunk
  1175.     MOVEM.L    A0/D1,-(SP)
  1176.     MOVEQ    #0,D0
  1177.     MOVE.B    n_glissfunk(A6),D0
  1178.     LSR.B    #4,D0
  1179.     BEQ.S    mt_funkend
  1180.     LEA    mt_FunkTable(PC),A0
  1181.     MOVE.B    (A0,D0.W),D0
  1182.     ADD.B    D0,n_funkoffset(A6)
  1183.     BTST    #7,n_funkoffset(A6)
  1184.     BEQ.S    mt_funkend
  1185.     CLR.B    n_funkoffset(A6)
  1186.  
  1187.     MOVE.L    n_loopstart(A6),D0
  1188.     MOVEQ    #0,D1
  1189.     MOVE.W    n_replen(A6),D1
  1190.     ADD.L    D1,D0
  1191.     ADD.L    D1,D0
  1192.     MOVE.L    n_wavestart(A6),A0
  1193.     ADDQ.L    #1,A0
  1194.     CMP.L    D0,A0
  1195.     BLO.S    mt_funkok
  1196.     MOVE.L    n_loopstart(A6),A0
  1197. mt_funkok
  1198.     MOVE.L    A0,n_wavestart(A6)
  1199.     MOVEQ    #-1,D0
  1200.     SUB.B    (A0),D0
  1201.     MOVE.B    D0,(A0)
  1202. mt_funkend
  1203.     MOVEM.L    (SP)+,A0/D1
  1204.     RTS
  1205.  
  1206.  
  1207. mt_FunkTable dc.b 0,5,6,7,8,10,11,13,16,19,22,26,32,43,64,128
  1208.  
  1209. mt_VibratoTable    
  1210.     dc.b   0, 24, 49, 74, 97,120,141,161
  1211.     dc.b 180,197,212,224,235,244,250,253
  1212.     dc.b 255,253,250,244,235,224,212,197
  1213.     dc.b 180,161,141,120, 97, 74, 49, 24
  1214.  
  1215. mt_PeriodTable
  1216. ; Tuning 0, Normal
  1217.     dc.w    856,808,762,720,678,640,604,570,538,508,480,453
  1218.     dc.w    428,404,381,360,339,320,302,285,269,254,240,226
  1219.     dc.w    214,202,190,180,170,160,151,143,135,127,120,113
  1220. ; Tuning 1
  1221.     dc.w    850,802,757,715,674,637,601,567,535,505,477,450
  1222.     dc.w    425,401,379,357,337,318,300,284,268,253,239,225
  1223.     dc.w    213,201,189,179,169,159,150,142,134,126,119,113
  1224. ; Tuning 2
  1225.     dc.w    844,796,752,709,670,632,597,563,532,502,474,447
  1226.     dc.w    422,398,376,355,335,316,298,282,266,251,237,224
  1227.     dc.w    211,199,188,177,167,158,149,141,133,125,118,112
  1228. ; Tuning 3
  1229.     dc.w    838,791,746,704,665,628,592,559,528,498,470,444
  1230.     dc.w    419,395,373,352,332,314,296,280,264,249,235,222
  1231.     dc.w    209,198,187,176,166,157,148,140,132,125,118,111
  1232. ; Tuning 4
  1233.     dc.w    832,785,741,699,660,623,588,555,524,495,467,441
  1234.     dc.w    416,392,370,350,330,312,294,278,262,247,233,220
  1235.     dc.w    208,196,185,175,165,156,147,139,131,124,117,110
  1236. ; Tuning 5
  1237.     dc.w    826,779,736,694,655,619,584,551,520,491,463,437
  1238.     dc.w    413,390,368,347,328,309,292,276,260,245,232,219
  1239.     dc.w    206,195,184,174,164,155,146,138,130,123,116,109
  1240. ; Tuning 6
  1241.     dc.w    820,774,730,689,651,614,580,547,516,487,460,434
  1242.     dc.w    410,387,365,345,325,307,290,274,258,244,230,217
  1243.     dc.w    205,193,183,172,163,154,145,137,129,122,115,109
  1244. ; Tuning 7
  1245.     dc.w    814,768,725,684,646,610,575,543,513,484,457,431
  1246.     dc.w    407,384,363,342,323,305,288,272,256,242,228,216
  1247.     dc.w    204,192,181,171,161,152,144,136,128,121,114,108
  1248. ; Tuning -8
  1249.     dc.w    907,856,808,762,720,678,640,604,570,538,508,480
  1250.     dc.w    453,428,404,381,360,339,320,302,285,269,254,240
  1251.     dc.w    226,214,202,190,180,170,160,151,143,135,127,120
  1252. ; Tuning -7
  1253.     dc.w    900,850,802,757,715,675,636,601,567,535,505,477
  1254.     dc.w    450,425,401,379,357,337,318,300,284,268,253,238
  1255.     dc.w    225,212,200,189,179,169,159,150,142,134,126,119
  1256. ; Tuning -6
  1257.     dc.w    894,844,796,752,709,670,632,597,563,532,502,474
  1258.     dc.w    447,422,398,376,355,335,316,298,282,266,251,237
  1259.     dc.w    223,211,199,188,177,167,158,149,141,133,125,118
  1260. ; Tuning -5
  1261.     dc.w    887,838,791,746,704,665,628,592,559,528,498,470
  1262.     dc.w    444,419,395,373,352,332,314,296,280,264,249,235
  1263.     dc.w    222,209,198,187,176,166,157,148,140,132,125,118
  1264. ; Tuning -4
  1265.     dc.w    881,832,785,741,699,660,623,588,555,524,494,467
  1266.     dc.w    441,416,392,370,350,330,312,294,278,262,247,233
  1267.     dc.w    220,208,196,185,175,165,156,147,139,131,123,117
  1268. ; Tuning -3
  1269.     dc.w    875,826,779,736,694,655,619,584,551,520,491,463
  1270.     dc.w    437,413,390,368,347,328,309,292,276,260,245,232
  1271.     dc.w    219,206,195,184,174,164,155,146,138,130,123,116
  1272. ; Tuning -2
  1273.     dc.w    868,820,774,730,689,651,614,580,547,516,487,460
  1274.     dc.w    434,410,387,365,345,325,307,290,274,258,244,230
  1275.     dc.w    217,205,193,183,172,163,154,145,137,129,122,115
  1276. ; Tuning -1
  1277.     dc.w    862,814,768,725,684,646,610,575,543,513,484,457
  1278.     dc.w    431,407,384,363,342,323,305,288,272,256,242,228
  1279.     dc.w    216,203,192,181,171,161,152,144,136,128,121,114
  1280.  
  1281. mt_chan1temp    dc.l    0,0,0,0,0,$00010000,0,  0,0,0,0
  1282. mt_chan2temp    dc.l    0,0,0,0,0,$00020000,0,  0,0,0,0
  1283. mt_chan3temp    dc.l    0,0,0,0,0,$00040000,0,  0,0,0,0
  1284. mt_chan4temp    dc.l    0,0,0,0,0,$00080000,0,  0,0,0,0
  1285.  
  1286. mt_SampleStarts    dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1287.         dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1288.  
  1289. mt_SongDataPtr    dc.l 0
  1290. mt_speed    dc.b 6
  1291. mt_counter    dc.b 0
  1292. mt_SongPos    dc.b 0
  1293. mt_PBreakPos    dc.b 0
  1294. mt_PosJumpFlag    dc.b 0
  1295. mt_PBreakFlag    dc.b 0
  1296. mt_LowMask    dc.b 0
  1297. mt_PattDelTime    dc.b 0
  1298. mt_PattDelTime2    dc.b 0
  1299. mt_Enable    dc.b 0
  1300. mt_PatternPos    dc.w 0
  1301. mt_DMACONtemp    dc.w 0
  1302.  
  1303. ;/* End of File */
  1304.